MATCH() KAÇINCI, İNDEX() İNDİS() Fonksiyonlarının kullanımı

Bazı tablolarda istenen değerleri bulabilmemiz için düşeyara fonksiyonunun yetersiz kaldığı durumlar olabilir,

Örneğin bir tabloda aranan değerin solunda kalan veriler istenebilir, bunun için aranan değerin bulunduğu sütunu en başa almamız gerekir,

Peki ya birden fazla değer istenirse her defasında sütun yerlerini mi değiştireceğiz?

Bu gibi durumlarda işimize yarayacak iki fonksiyonun birlikte kullanımını öğreneceğiz MATCH() KAÇINCI() VE İNDEX() İNDİS() fonksiyonları

Öncelikle yine basit bir örnekle bu fonksiyonların kullanımlarını öğrenelim sonra iki fonksiyonu birarada kullanacağımız bir örnek yapalım.

·         MATCH() KAÇINCI() fonksiyonu bize seçili tablomuzdaki sıralamaya göre aranan değerin göreceli sıra numarasını döndürür.

       KAÇINCI(aranan_değer;aranan_dizi;eşleştir_tür) => KAÇINCI(aradığım değer;hangi tabloda;tam eşleşme istiyorsak burayı "0" gireceğiz)

Örnek 1: Kırmızı ve turuncu renklerin tablomuzdaki göreceli sıralamasını bulalım:

·        İNDEX() İNDİS ()fonksiyonu ise ilgili dizideki verilen satır ve sütun numarasındaki değeri döndürür.

        İNDİS(dizi;satırsayısı;sütunsayısı) => İNDİS(tablom;kaçıncı satır;kaçıncı sütun) buradaki değeri döndürür.

Örnek 2: Sarı rengin renk numarasına ulaşalım:

 Ancak her indis hesaplamasında aradığım hücrenin kaçıncı satırda olduğunu bilemeyeceğim için satır numarası yerine kaçıncı fonksiyonunu girersek bize ilgili satır değerini otomatik getirecektir.

             Örnek 3: Turuncu rengin renk numarasını bulalım.

	A	B	C	D	E	F	G	H
1
2		renkler	renk numarası
3		mavi	a1
4		sarı	a2		Örnek1:
5		kırmızı	a3		kırmızı	3	=KAÇINCI(E5;B3:B9;0) kırmızı değeri tablomda kaçıncı sırada
6		yeşil	a4		turuncu	6	=KAÇINCI(E6;B3:B9;0)
7		mor	a5
8		turuncu	a6		Örnek2:
9		kahverengi	a7		sarı	a2	=İNDİS(B3:C9;2;2)
10							yani ilgili tablomda 2. satır, 2. sütundaki değeri getir.
11					Örnek3 :
12					turuncu	a6	=İNDİS(C3:C9;KAÇINCI(E12;B3:B9;0);1)
13

Şimdi daha karışık bir satış tablosu üzerinde bizden istenen değerleri bulmaya çalışalım:

	A	B	C	D	E	F	G	H
1
2	satışçı	müşteri sayısı	satışlar	kar
3	ali	9	2257	764
4	selin	9	2466	695		en çok satışı kim yapmış?	selin	=İNDİS(A3:A15;KAÇINCI(MAK(C3:C15);C3:C15;0);1)
5	metin	13	2251	620		en çok 2. satışı kim yapmış?	ceyhun	=İNDİS(A3:A15;KAÇINCI(BÜYÜK(C3:C15;2);C3:C15;0);1)
6	ece	12	1650	515		en az kim kar etmiş?	ece	=İNDİS(A3:A15;KAÇINCI(MİN(D3:D15);D3:D15;0);1)
7	ahmet	9	2133	555		sinan'nın müşteri sayısı nedir?	14	=İNDİS(B3:B15;KAÇINCI("sinan";A3:A15;0);1)
8	ceyhun	13	2461	727
9	ceren	12	1466	779
10	sinan	14	2214	575
11	gökhan	14	1987	797
12	can	9	2018	576
13	eda	7	2136	684
14	kerem	13	1720	747
15	nihat	9	2423	594
16